/**
* code by André Mattos - www.ma77os.com
* Licenced under Creative Commons - http://creativecommons.org/licenses/by-sa/3.0/
**/
var nParticles:Number = 350;
var count:uint = 0;
var vyAmount:Number = 8;
var particlesContainer:Sprite;
var upForce:Number = -0.5;
var arrParticles:Array = new Array ();
var spreadForce:Number = 0.4;
 
init ()
 
function init ()
{
	particlesContainer = new Sprite ();
	addChild (particlesContainer)
 
	addEventListener (Event.ENTER_FRAME, moveParticles);
	stage.addEventListener (MouseEvent.MOUSE_DOWN, spreadParticles);
}
 
function moveParticles (evt:Event)
{
	createParticle (5);
 
	for (var a:uint = 0; a < arrParticles.length; a++)
	{
		var particle:Object = arrParticles[a];
 
		particle.vx += Math.cos (particle.angleVX) * particle.radiusVX;
		particle.vy += (particle.vyDest - particle.vy) * 0.4;
		particle.vx *= 0.4;
 
		particle.shape.x += particle.vx;
		particle.shape.y += particle.vy;
 
		particle.angleVX += particle.speedAngle;
 
		if (particle.shape.y < -10)
		{
			restartParticle (particle)
		}
	}
}
function createParticle (amount:uint = 1)
{
	if (count >= nParticles) return;
 
	for (var a:uint = 0; a < amount; a++)
	{
		var particle:Object = new Object ()
		particle.shape = new Shape ()
		particle.shape.graphics.beginFill (0x00CCFF, 1);
		particle.shape.graphics.drawCircle (0, 0, 2.5);
		particle.shape.graphics.endFill ()
 
		particlesContainer.addChild(particle.shape);
 
		arrParticles.push (particle);
		restartParticle (particle);
 
		particle.shape.cacheAsBitmap = true;
 
		count++;
	}
}
 
function restartParticle (particle:Object)
{
	var xCenter:Number = stage.stageWidth / 2 + (Math.random () * 20 - 10);
	var outCenter:Boolean = Math.random() * 10 < 3;
 
	particle.shape.x = outCenter ? Math.random() * stage.stageWidth : xCenter;
	particle.shape.y = stage.stageHeight;
	particle.vx = 0;
	particle.vy = 0;
	particle.vyDest = Math.random () * vyAmount / 2 - vyAmount;
	particle.angleVX = Math.random () * Math.PI * 2;
	particle.radiusVX = Math.random () * 1;
	particle.speedAngle = Math.random () * 0.05;
	particle.shape.scaleX = particle.shape.scaleY = Math.random () * 1 + 0.7;
	particle.shape.alpha = outCenter ? 0.1 + Math.random() * 0.15 : 0.4 + Math.random() * 0.6;
}
 
function spreadParticles (evt:MouseEvent)
{
	for (var a:uint = 0; a < arrParticles.length; a++)
	{
		var particle:Object = arrParticles[a];
		var dx:Number = mouseX - particle.shape.x;
		var dy:Number = mouseY - particle.shape.y;
		var dist:Number = Math.sqrt(dx * dx + dy * dy)
		var angle:Number = Math.atan2(dy, dx);
 
		particle.vx -= Math.cos(angle) * Math.abs(stage.stageWidth - dist)* spreadForce;
		particle.vy -= Math.sin(angle) * Math.abs(stage.stageHeight - dist) * spreadForce / 2
	}
}